Perl 5 version 22.4 documentation

sort

Perl functions A-Z | Perl functions by category | The 'perlfunc' manpage
  • sort SUBNAME LIST

  • sort BLOCK LIST
  • sort LIST

    In list context, this sorts the LIST and returns the sorted list value. In scalar context, the behaviour of sort() is undefined.

    If SUBNAME or BLOCK is omitted, sorts in standard string comparison order. If SUBNAME is specified, it gives the name of a subroutine that returns an integer less than, equal to, or greater than , depending on how the elements of the list are to be ordered. (The <=> and cmp operators are extremely useful in such routines.) SUBNAME may be a scalar variable name (unsubscripted), in which case the value provides the name of (or a reference to) the actual subroutine to use. In place of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort subroutine.

    If the subroutine's prototype is ($$) , the elements to be compared are passed by reference in @_ , as for a normal subroutine. This is slower than unprototyped subroutines, where the elements to be compared are passed into the subroutine as the package global variables $a and $b (see example below). Note that in the latter case, it is usually highly counter-productive to declare $a and $b as lexicals.

    If the subroutine is an XSUB, the elements to be compared are pushed on to the stack, the way arguments are usually passed to XSUBs. $a and $b are not set.

    The values to be compared are always passed by reference and should not be modified.

    You also cannot exit out of the sort block or subroutine using any of the loop control operators described in perlsyn or with goto.

    When use locale (but not use locale 'not_characters' ) is in effect, sort LIST sorts LIST according to the current collation locale. See perllocale.

    sort() returns aliases into the original list, much as a for loop's index variable aliases the list elements. That is, modifying an element of a list returned by sort() (for example, in a foreach, map or grep) actually modifies the element in the original list. This is usually something to be avoided when writing clear code.

    Perl 5.6 and earlier used a quicksort algorithm to implement sort. That algorithm was not stable, so could go quadratic. (A stable sort preserves the input order of elements that compare equal. Although quicksort's run time is O(NlogN) when averaged over all arrays of length N, the time can be O(N**2), quadratic behavior, for some inputs.) In 5.7, the quicksort implementation was replaced with a stable mergesort algorithm whose worst-case behavior is O(NlogN). But benchmarks indicated that for some inputs, on some platforms, the original quicksort was faster. 5.8 has a sort pragma for limited control of the sort. Its rather blunt control of the underlying algorithm may not persist into future Perls, but the ability to characterize the input or output in implementation independent ways quite probably will. See the sort pragma.

    Examples:

    1.     # sort lexically
    2.     @articles = sort @files;
    4.     # same thing, but with explicit sort routine
    5.     @articles = sort {$a cmp $b} @files;
    7.     # now case-insensitively
    8.     @articles = sort {fc($a) cmp fc($b)} @files;
    10.     # same thing in reversed order
    11.     @articles = sort {$b cmp $a} @files;
    13.     # sort numerically ascending
    14.     @articles = sort {$a <=> $b} @files;
    16.     # sort numerically descending
    17.     @articles = sort {$b <=> $a} @files;
    19.     # this sorts the %age hash by value instead of key
    20.     # using an in-line function
    21.     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
    23.     # sort using explicit subroutine name
    24.     sub byage {
    25.         $age{$a} <=> $age{$b};  # presuming numeric
    26.     }
    27.     @sortedclass = sort byage @class;
    29.     sub backwards { $b cmp $a }
    30.     @harry  = qw(dog cat x Cain Abel);
    31.     @george = qw(gone chased yz Punished Axed);
    32.     print sort @harry;
    33.         # prints AbelCaincatdogx
    34.     print sort backwards @harry;
    35.         # prints xdogcatCainAbel
    36.     print sort @george, 'to', @harry;
    37.         # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
    39.     # inefficiently sort by descending numeric compare using
    40.     # the first integer after the first = sign, or the
    41.     # whole record case-insensitively otherwise
    43.     my @new = sort {
    44.         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
    45.                             ||
    46.                     fc($a)  cmp  fc($b)
    47.     } @old;
    49.     # same thing, but much more efficiently;
    50.     # we'll build auxiliary indices instead
    51.     # for speed
    52.     my (@nums, @caps);
    53.     for (@old) {
    54.         push @nums, ( /=(\d+)/ ? $1 : undef );
    55.         push @caps, fc($_);
    56.     }
    58.     my @new = @old[ sort {
    59.                            $nums[$b] <=> $nums[$a]
    60.                                     ||
    61.                            $caps[$a] cmp $caps[$b]
    62.                          } 0..$#old
    63.                   ];
    65.     # same thing, but without any temps
    66.     @new = map { $_->[0] }
    67.            sort { $b->[1] <=> $a->[1]
    68.                            ||
    69.                   $a->[2] cmp $b->[2]
    70.            } map { [$_, /=(\d+)/, fc($_)] } @old;
    72.     # using a prototype allows you to use any comparison subroutine
    73.     # as a sort subroutine (including other package's subroutines)
    74.     package other;
    75.     sub backwards ($$) { $_[1] cmp $_[0]; }  # $a and $b are
    76.                                              # not set here    
    77.     package main;
    78.     @new = sort other::backwards @old;
    80.     # guarantee stability, regardless of algorithm
    81.     use sort 'stable';
    82.     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
    84.     # force use of mergesort (not portable outside Perl 5.8)
    85.     use sort '_mergesort';  # note discouraging _
    86.     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;

    Warning: syntactical care is required when sorting the list returned from a function. If you want to sort the list returned by the function call find_records(@key) , you can use:

    1.     @contact = sort { $a cmp $b } find_records @key;
    2.     @contact = sort +find_records(@key);
    3.     @contact = sort &find_records(@key);
    4.     @contact = sort(find_records(@key));

    If instead you want to sort the array @key with the comparison routine find_records() then you can use:

    1.     @contact = sort { find_records() } @key;
    2.     @contact = sort find_records(@key);
    3.     @contact = sort(find_records @key);
    4.     @contact = sort(find_records (@key));

    If you're using strict, you must not declare $a and $b as lexicals. They are package globals. That means that if you're in the main package and type

    1.     @articles = sort {$b <=> $a} @files;

    then $a and $b are $main::a and $main::b (or $::a and $::b ), but if you're in the FooPack package, it's the same as typing

    1.     @articles = sort {$FooPack::b <=> $FooPack::a} @files;

    The comparison function is required to behave. If it returns inconsistent results (sometimes saying $x[1] is less than $x[2] and sometimes saying the opposite, for example) the results are not well-defined.

    Because <=> returns undef when either operand is NaN (not-a-number), be careful when sorting with a comparison function like $a <=> $b any lists that might contain a NaN . The following example takes advantage that NaN != NaN to eliminate any NaN s from the input list.

    1.     @result = sort { $a <=> $b } grep { $_ == $_ } @input;