Perl 5 version 32.0 documentation

feature

NAME

feature - Perl pragma to enable new features

SYNOPSIS

  1.     use feature qw(say switch);
  2.     given ($foo) {
  3.         when (1)          { say "\$foo == 1" }
  4.         when ([2,3])      { say "\$foo == 2 || \$foo == 3" }
  5.         when (/^a[bc]d$/) { say "\$foo eq 'abd' || \$foo eq 'acd'" }
  6.         when ($_ > 100)   { say "\$foo > 100" }
  7.         default           { say "None of the above" }
  8.     }
  10.     use feature ':5.10'; # loads all features available in perl 5.10
  12.     use v5.10;           # implicitly loads :5.10 feature bundle

DESCRIPTION

It is usually impossible to add new syntax to Perl without breaking some existing programs. This pragma provides a way to minimize that risk. New syntactic constructs, or new semantic meanings to older constructs, can be enabled by use feature 'foo' , and will be parsed only when the appropriate feature pragma is in scope. (Nevertheless, the CORE:: prefix provides access to all Perl keywords, regardless of this pragma.)

Lexical effect

Like other pragmas (use strict , for example), features have a lexical effect. use feature qw(foo) will only make the feature "foo" available from that point to the end of the enclosing block.

  1.     {
  2.         use feature 'say';
  3.         say "say is available here";
  4.     }
  5.     print "But not here.\n";

no feature

Features can also be turned off by using no feature "foo" . This too has lexical effect.

  1.     use feature 'say';
  2.     say "say is available here";
  3.     {
  4.         no feature 'say';
  5.         print "But not here.\n";
  6.     }
  7.     say "Yet it is here.";

no feature with no features specified will reset to the default group. To disable all features (an unusual request!) use no feature ':all' .

AVAILABLE FEATURES

The 'say' feature

use feature 'say' tells the compiler to enable the Perl 6 style say function.

See say for details.

This feature is available starting with Perl 5.10.

The 'state' feature

use feature 'state' tells the compiler to enable state variables.

See Persistent Private Variables in perlsub for details.

This feature is available starting with Perl 5.10.

The 'switch' feature

WARNING: Because the smartmatch operator is experimental, Perl will warn when you use this feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::smartmatch";

use feature 'switch' tells the compiler to enable the Perl 6 given/when construct.

See Switch Statements in perlsyn for details.

This feature is available starting with Perl 5.10.

The 'unicode_strings' feature

use feature 'unicode_strings' tells the compiler to use Unicode rules in all string operations executed within its scope (unless they are also within the scope of either use locale or use bytes ). The same applies to all regular expressions compiled within the scope, even if executed outside it. It does not change the internal representation of strings, but only how they are interpreted.

no feature 'unicode_strings' tells the compiler to use the traditional Perl rules wherein the native character set rules is used unless it is clear to Perl that Unicode is desired. This can lead to some surprises when the behavior suddenly changes. (See The Unicode Bug in perlunicode for details.) For this reason, if you are potentially using Unicode in your program, the use feature 'unicode_strings' subpragma is strongly recommended.

This feature is available starting with Perl 5.12; was almost fully implemented in Perl 5.14; and extended in Perl 5.16 to cover quotemeta; was extended further in Perl 5.26 to cover the range operator; and was extended again in Perl 5.28 to cover split.

The 'unicode_eval' and 'evalbytes' features

Together, these two features are intended to replace the legacy string eval function, which behaves problematically in some instances. They are available starting with Perl 5.16, and are enabled by default by a use 5.16 or higher declaration.

unicode_eval changes the behavior of plain string eval to work more consistently, especially in the Unicode world. Certain (mis)behaviors couldn't be changed without breaking some things that had come to rely on them, so the feature can be enabled and disabled. Details are at Under the unicode_eval feature in perlfunc.

evalbytes is like string eval, but operating on a byte stream that is not UTF-8 encoded. Details are at evalbytes EXPR. Without a use feature 'evalbytes' nor a use v5.16 (or higher) declaration in the current scope, you can still access it by instead writing CORE::evalbytes .

The 'current_sub' feature

This provides the __SUB__ token that returns a reference to the current subroutine or undef outside of a subroutine.

This feature is available starting with Perl 5.16.

The 'array_base' feature

This feature supported the legacy $[ variable. See $[ in perlvar. It was on by default but disabled under use v5.16 (see IMPLICIT LOADING, below) and unavailable since perl 5.30.

This feature is available under this name starting with Perl 5.16. In previous versions, it was simply on all the time, and this pragma knew nothing about it.

The 'fc' feature

use feature 'fc' tells the compiler to enable the fc function, which implements Unicode casefolding.

See fc for details.

This feature is available from Perl 5.16 onwards.

The 'lexical_subs' feature

In Perl versions prior to 5.26, this feature enabled declaration of subroutines via my sub foo , state sub foo and our sub foo syntax. See Lexical Subroutines in perlsub for details.

This feature is available from Perl 5.18 onwards. From Perl 5.18 to 5.24, it was classed as experimental, and Perl emitted a warning for its usage, except when explicitly disabled:

  1.   no warnings "experimental::lexical_subs";

As of Perl 5.26, use of this feature no longer triggers a warning, though the experimental::lexical_subs warning category still exists (for compatibility with code that disables it). In addition, this syntax is not only no longer experimental, but it is enabled for all Perl code, regardless of what feature declarations are in scope.

The 'postderef' and 'postderef_qq' features

The 'postderef_qq' feature extends the applicability of postfix dereference syntax so that postfix array and scalar dereference are available in double-quotish interpolations. For example, it makes the following two statements equivalent:

  1.   my $s = "[@{ $h->{a} }]";
  2.   my $s = "[$h->{a}->@*]";

This feature is available from Perl 5.20 onwards. In Perl 5.20 and 5.22, it was classed as experimental, and Perl emitted a warning for its usage, except when explicitly disabled:

  1.   no warnings "experimental::postderef";

As of Perl 5.24, use of this feature no longer triggers a warning, though the experimental::postderef warning category still exists (for compatibility with code that disables it).

The 'postderef' feature was used in Perl 5.20 and Perl 5.22 to enable postfix dereference syntax outside double-quotish interpolations. In those versions, using it triggered the experimental::postderef warning in the same way as the 'postderef_qq' feature did. As of Perl 5.24, this syntax is not only no longer experimental, but it is enabled for all Perl code, regardless of what feature declarations are in scope.

The 'signatures' feature

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::signatures";

This enables unpacking of subroutine arguments into lexical variables by syntax such as

  1.     sub foo ($left, $right) {
  2. 	return $left + $right;
  3.     }

See Signatures in perlsub for details.

This feature is available from Perl 5.20 onwards.

The 'refaliasing' feature

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::refaliasing";

This enables aliasing via assignment to references:

  1.     \$a = \$b; # $a and $b now point to the same scalar
  2.     \@a = \@b; #                     to the same array
  3.     \%a = \%b;
  4.     \&a = \&b;
  5.     foreach \%hash (@array_of_hash_refs) {
  6.         ...
  7.     }

See Assigning to References in perlref for details.

This feature is available from Perl 5.22 onwards.

The 'bitwise' feature

This makes the four standard bitwise operators (& | ^ ~ ) treat their operands consistently as numbers, and introduces four new dotted operators (&. |. ^. ~. ) that treat their operands consistently as strings. The same applies to the assignment variants (&= |= ^= &.= |.= ^.= ).

See Bitwise String Operators in perlop for details.

This feature is available from Perl 5.22 onwards. Starting in Perl 5.28, use v5.28 will enable the feature. Before 5.28, it was still experimental and would emit a warning in the "experimental::bitwise" category.

The 'declared_refs' feature

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::declared_refs";

This allows a reference to a variable to be declared with my, state, our our, or localized with local. It is intended mainly for use in conjunction with the "refaliasing" feature. See Declaring a Reference to a Variable in perlref for examples.

This feature is available from Perl 5.26 onwards.

The 'isa' feature

This allows the use of the isa infix operator, which tests whether the scalar given by the left operand is an object of the class given by the right operand. See Class Instance Operator in perlop for more details.

This feature is available from Perl 5.32 onwards.

The 'indirect' feature

This feature allows the use of indirect object syntax for method calls, e.g. new Foo 1, 2; . It is enabled by default, but can be turned off to disallow indirect object syntax.

This feature is available under this name from Perl 5.32 onwards. In previous versions, it was simply on all the time. To disallow (or warn on) indirect object syntax on older Perls, see the indirect CPAN module.

FEATURE BUNDLES

It's possible to load multiple features together, using a feature bundle. The name of a feature bundle is prefixed with a colon, to distinguish it from an actual feature.

  1.   use feature ":5.10";

The following feature bundles are available:

  1.   bundle    features included
  2.   --------- -----------------
  3.   :default  indirect
  5.   :5.10     say state switch indirect
  7.   :5.12     say state switch unicode_strings indirect
  9.   :5.14     say state switch unicode_strings indirect
  11.   :5.16     say state switch unicode_strings
  12.             unicode_eval evalbytes current_sub fc
  13.             indirect
  15.   :5.18     say state switch unicode_strings
  16.             unicode_eval evalbytes current_sub fc
  17.             indirect
  19.   :5.20     say state switch unicode_strings
  20.             unicode_eval evalbytes current_sub fc
  21.             indirect
  23.   :5.22     say state switch unicode_strings
  24.             unicode_eval evalbytes current_sub fc
  25.             indirect
  27.   :5.24     say state switch unicode_strings
  28.             unicode_eval evalbytes current_sub fc
  29.             postderef_qq indirect
  31.   :5.26     say state switch unicode_strings
  32.             unicode_eval evalbytes current_sub fc
  33.             postderef_qq indirect
  35.   :5.28     say state switch unicode_strings
  36.             unicode_eval evalbytes current_sub fc
  37.             postderef_qq bitwise indirect
  39.   :5.30     say state switch unicode_strings
  40.             unicode_eval evalbytes current_sub fc
  41.             postderef_qq bitwise indirect
  43.   :5.32     say state switch unicode_strings
  44.             unicode_eval evalbytes current_sub fc
  45.             postderef_qq bitwise indirect

The :default bundle represents the feature set that is enabled before any use feature or no feature declaration.

Specifying sub-versions such as the in 5.14.0 in feature bundles has no effect. Feature bundles are guaranteed to be the same for all sub-versions.

  1.   use feature ":5.14.0";    # same as ":5.14"
  2.   use feature ":5.14.1";    # same as ":5.14"

IMPLICIT LOADING

Instead of loading feature bundles by name, it is easier to let Perl do implicit loading of a feature bundle for you.

There are two ways to load the feature pragma implicitly:

  • By using the -E switch on the Perl command-line instead of -e . That will enable the feature bundle for that version of Perl in the main compilation unit (that is, the one-liner that follows -E ).

  • By explicitly requiring a minimum Perl version number for your program, with the use VERSION construct. That is,

    1.     use v5.10.0;

    will do an implicit

    1.     no feature ':all';
    2.     use feature ':5.10';

    and so on. Note how the trailing sub-version is automatically stripped from the version.

    But to avoid portability warnings (see use), you may prefer:

    1.     use 5.010;

    with the same effect.

    If the required version is older than Perl 5.10, the ":default" feature bundle is automatically loaded instead.

    Unlike use feature ":5.12" , saying use v5.12 (or any higher version) also does the equivalent of use strict ; see use for details.