Perl 5 version 26.3 documentation

Test2::Util::HashBase

NAME

Test2::Util::HashBase - Build hash based classes.

SYNOPSIS

A class:

  1.     package My::Class;
  2.     use strict;
  3.     use warnings;
  5.     # Generate 3 accessors
  6.     use Test2::Util::HashBase qw/foo -bar ^baz/;
  8.     # Chance to initialize defaults
  9.     sub init {
  10.         my $self = shift;    # No other args
  11.         $self->{+FOO} ||= "foo";
  12.         $self->{+BAR} ||= "bar";
  13.         $self->{+BAZ} ||= "baz";
  14.     }
  16.     sub print {
  17.         print join ", " => map { $self->{$_} } FOO, BAR, BAZ;
  18.     }

Subclass it

  1.     package My::Subclass;
  2.     use strict;
  3.     use warnings;
  5.     # Note, you should subclass before loading HashBase.
  6.     use base 'My::Class';
  7.     use Test2::Util::HashBase qw/bat/;
  9.     sub init {
  10.         my $self = shift;
  12.         # We get the constants from the base class for free.
  13.         $self->{+FOO} ||= 'SubFoo';
  14.         $self->{+BAT} ||= 'bat';
  16.         $self->SUPER::init();
  17.     }

use it:

  1.     package main;
  2.     use strict;
  3.     use warnings;
  4.     use My::Class;
  6.     my $one = My::Class->new(foo => 'MyFoo', bar => 'MyBar');
  8.     # Accessors!
  9.     my $foo = $one->foo;    # 'MyFoo'
  10.     my $bar = $one->bar;    # 'MyBar'
  11.     my $baz = $one->baz;    # Defaulted to: 'baz'
  13.     # Setters!
  14.     $one->set_foo('A Foo');
  16.     #'-bar' means read-only, so the setter will throw an exception (but is defined).
  17.     $one->set_bar('A bar');
  19.     # '^baz' means deprecated setter, this will warn about the setter being
  20.     # deprecated.
  21.     $one->set_baz('A Baz');
  23.     $one->{+FOO} = 'xxx';

DESCRIPTION

This package is used to generate classes based on hashrefs. Using this class will give you a new() method, as well as generating accessors you request. Generated accessors will be getters, set_ACCESSOR setters will also be generated for you. You also get constants for each accessor (all caps) which return the key into the hash for that accessor. Single inheritance is also supported.

THIS IS A BUNDLED COPY OF HASHBASE

This is a bundled copy of Object::HashBase. This file was generated using the /home/exodist/perl5/perlbrew/perls/main/bin/hashbase_inc.pl script.

METHODS

PROVIDED BY HASH BASE

  • $it = $class->new(@VALUES)

    Create a new instance using key/value pairs.

    HashBase will not export new() if there is already a new() method in your packages inheritance chain.

    If you do not want this method you can define your own you just have to declare it before loading Test2::Util::HashBase.

    1.     package My::Package;
    3.     # predeclare new() so that HashBase does not give us one.
    4.     sub new;
    6.     use Test2::Util::HashBase qw/foo bar baz/;
    8.     # Now we define our own new method.
    9.     sub new { ... }

    This makes it so that HashBase sees that you have your own new() method. Alternatively you can define the method before loading HashBase instead of just declaring it, but that scatters your use statements.

HOOKS

  • $self->init()

    This gives you the chance to set some default values to your fields. The only argument is $self with its indexes already set from the constructor.

ACCESSORS

To generate accessors you list them when using the module:

  1.     use Test2::Util::HashBase qw/foo/;

This will generate the following subs in your namespace:

  • foo()

    Getter, used to get the value of the foo field.

  • set_foo()

    Setter, used to set the value of the foo field.

  • FOO()

    Constant, returns the field foo 's key into the class hashref. Subclasses will also get this function as a constant, not simply a method, that means it is copied into the subclass namespace.

    The main reason for using these constants is to help avoid spelling mistakes and similar typos. It will not help you if you forget to prefix the '+' though.

SUBCLASSING

You can subclass an existing HashBase class.

  1.     use base 'Another::HashBase::Class';
  2.     use Test2::Util::HashBase qw/foo bar baz/;

The base class is added to @ISA for you, and all constants from base classes are added to subclasses automatically.

SOURCE

The source code repository for HashBase can be found at http://github.com/Test-More/HashBase/.

MAINTAINERS

  • Chad Granum <exodist@cpan.org>

AUTHORS

  • Chad Granum <exodist@cpan.org>

COPYRIGHT

Copyright 2016 Chad Granum <exodist@cpan.org>.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

See http://dev.perl.org/licenses/