Perl 5 version 24.3 documentation

List::Util

NAME

List::Util - A selection of general-utility list subroutines

SYNOPSIS

  1.     use List::Util qw(first max maxstr min minstr reduce shuffle sum);

DESCRIPTION

List::Util contains a selection of subroutines that people have expressed would be nice to have in the perl core, but the usage would not really be high enough to warrant the use of a keyword, and the size so small such that being individual extensions would be wasteful.

By default List::Util does not export any subroutines.

LIST-REDUCTION FUNCTIONS

The following set of functions all reduce a list down to a single value.

$result = reduce { BLOCK } @list

Reduces @list by calling BLOCK in a scalar context multiple times, setting $a and $b each time. The first call will be with $a and $b set to the first two elements of the list, subsequent calls will be done by setting $a to the result of the previous call and $b to the next element in the list.

Returns the result of the last call to the BLOCK . If @list is empty then undef is returned. If @list only contains one element then that element is returned and BLOCK is not executed.

The following examples all demonstrate how reduce could be used to implement the other list-reduction functions in this module. (They are not in fact implemented like this, but instead in a more efficient manner in individual C functions).

  1.     $foo = reduce { defined($a)            ? $a :
  2.                     $code->(local $_ = $b) ? $b :
  3.                                              undef } undef, @list # first
  5.     $foo = reduce { $a > $b ? $a : $b } 1..10       # max
  6.     $foo = reduce { $a gt $b ? $a : $b } 'A'..'Z'   # maxstr
  7.     $foo = reduce { $a < $b ? $a : $b } 1..10       # min
  8.     $foo = reduce { $a lt $b ? $a : $b } 'aa'..'zz' # minstr
  9.     $foo = reduce { $a + $b } 1 .. 10               # sum
  10.     $foo = reduce { $a . $b } @bar                  # concat
  12.     $foo = reduce { $a || $code->(local $_ = $b) } 0, @bar   # any
  13.     $foo = reduce { $a && $code->(local $_ = $b) } 1, @bar   # all
  14.     $foo = reduce { $a && !$code->(local $_ = $b) } 1, @bar  # none
  15.     $foo = reduce { $a || !$code->(local $_ = $b) } 0, @bar  # notall
  16.        # Note that these implementations do not fully short-circuit

If your algorithm requires that reduce produce an identity value, then make sure that you always pass that identity value as the first argument to prevent undef being returned

  1.   $foo = reduce { $a + $b } 0, @values;             # sum with 0 identity value

The remaining list-reduction functions are all specialisations of this generic idea.

any

  1.     my $bool = any { BLOCK } @list;

Since version 1.33.

Similar to grep in that it evaluates BLOCK setting $_ to each element of @list in turn. any returns true if any element makes the BLOCK return a true value. If BLOCK never returns true or @list was empty then it returns false.

Many cases of using grep in a conditional can be written using any instead, as it can short-circuit after the first true result.

  1.     if( any { length > 10 } @strings ) {
  2.         # at least one string has more than 10 characters
  3.     }

all

  1.     my $bool = all { BLOCK } @list;

Since version 1.33.

Similar to any, except that it requires all elements of the @list to make the BLOCK return true. If any element returns false, then it returns false. If the BLOCK never returns false or the @list was empty then it returns true.

none

notall

  1.     my $bool = none { BLOCK } @list;
  3.     my $bool = notall { BLOCK } @list;

Since version 1.33.

Similar to any and all, but with the return sense inverted. none returns true only if no value in the @list causes the BLOCK to return true, and notall returns true only if not all of the values do.

first

  1.     my $val = first { BLOCK } @list;

Similar to grep in that it evaluates BLOCK setting $_ to each element of @list in turn. first returns the first element where the result from BLOCK is a true value. If BLOCK never returns true or @list was empty then undef is returned.

  1.     $foo = first { defined($_) } @list    # first defined value in @list
  2.     $foo = first { $_ > $value } @list    # first value in @list which
  3.                                           # is greater than $value

max

  1.     my $num = max @list;

Returns the entry in the list with the highest numerical value. If the list is empty then undef is returned.

  1.     $foo = max 1..10                # 10
  2.     $foo = max 3,9,12               # 12
  3.     $foo = max @bar, @baz           # whatever

maxstr

  1.     my $str = maxstr @list;

Similar to max, but treats all the entries in the list as strings and returns the highest string as defined by the gt operator. If the list is empty then undef is returned.

  1.     $foo = maxstr 'A'..'Z'          # 'Z'
  2.     $foo = maxstr "hello","world"   # "world"
  3.     $foo = maxstr @bar, @baz        # whatever

min

  1.     my $num = min @list;

Similar to max but returns the entry in the list with the lowest numerical value. If the list is empty then undef is returned.

  1.     $foo = min 1..10                # 1
  2.     $foo = min 3,9,12               # 3
  3.     $foo = min @bar, @baz           # whatever

minstr

  1.     my $str = minstr @list;

Similar to min, but treats all the entries in the list as strings and returns the lowest string as defined by the lt operator. If the list is empty then undef is returned.

  1.     $foo = minstr 'A'..'Z'          # 'A'
  2.     $foo = minstr "hello","world"   # "hello"
  3.     $foo = minstr @bar, @baz        # whatever

product

  1.     my $num = product @list;

Since version 1.35.

Returns the numerical product of all the elements in @list . If @list is empty then 1 is returned.

  1.     $foo = product 1..10            # 3628800
  2.     $foo = product 3,9,12           # 324

sum

  1.     my $num_or_undef = sum @list;

Returns the numerical sum of all the elements in @list . For backwards compatibility, if @list is empty then undef is returned.

  1.     $foo = sum 1..10                # 55
  2.     $foo = sum 3,9,12               # 24
  3.     $foo = sum @bar, @baz           # whatever

sum0

  1.     my $num = sum0 @list;

Since version 1.26.

Similar to sum, except this returns 0 when given an empty list, rather than undef.

KEY/VALUE PAIR LIST FUNCTIONS

The following set of functions, all inspired by List::Pairwise, consume an even-sized list of pairs. The pairs may be key/value associations from a hash, or just a list of values. The functions will all preserve the original ordering of the pairs, and will not be confused by multiple pairs having the same "key" value - nor even do they require that the first of each pair be a plain string.

NOTE: At the time of writing, the following pair* functions that take a block do not modify the value of $_ within the block, and instead operate using the $a and $b globals instead. This has turned out to be a poor design, as it precludes the ability to provide a pairsort function. Better would be to pass pair-like objects as 2-element array references in $_ , in a style similar to the return value of the pairs function. At some future version this behaviour may be added.

Until then, users are alerted NOT to rely on the value of $_ remaining unmodified between the outside and the inside of the control block. In particular, the following example is UNSAFE:

  1.  my @kvlist = ...
  3.  foreach (qw( some keys here )) {
  4.     my @items = pairgrep { $a eq $_ } @kvlist;
  5.     ...
  6.  }

Instead, write this using a lexical variable:

  1.  foreach my $key (qw( some keys here )) {
  2.     my @items = pairgrep { $a eq $key } @kvlist;
  3.     ...
  4.  }

pairs

  1.     my @pairs = pairs @kvlist;

Since version 1.29.

A convenient shortcut to operating on even-sized lists of pairs, this function returns a list of ARRAY references, each containing two items from the given list. It is a more efficient version of

  1.     @pairs = pairmap { [ $a, $b ] } @kvlist

It is most convenient to use in a foreach loop, for example:

  1.     foreach my $pair ( pairs @KVLIST ) {
  2.        my ( $key, $value ) = @$pair;
  3.        ...
  4.     }

Since version 1.39 these ARRAY references are blessed objects, recognising the two methods key and value . The following code is equivalent:

  1.     foreach my $pair ( pairs @KVLIST ) {
  2.        my $key   = $pair->key;
  3.        my $value = $pair->value;
  4.        ...
  5.     }

unpairs

  1.     my @kvlist = unpairs @pairs

Since version 1.42.

The inverse function to pairs ; this function takes a list of ARRAY references containing two elements each, and returns a flattened list of the two values from each of the pairs, in order. This is notionally equivalent to

  1.     my @kvlist = map { @{$_}[0,1] } @pairs

except that it is implemented more efficiently internally. Specifically, for any input item it will extract exactly two values for the output list; using undef if the input array references are short.

Between pairs and unpairs , a higher-order list function can be used to operate on the pairs as single scalars; such as the following near-equivalents of the other pair* higher-order functions:

  1.     @kvlist = unpairs grep { FUNC } pairs @kvlist
  2.     # Like pairgrep, but takes $_ instead of $a and $b
  4.     @kvlist = unpairs map { FUNC } pairs @kvlist
  5.     # Like pairmap, but takes $_ instead of $a and $b

Note however that these versions will not behave as nicely in scalar context.

Finally, this technique can be used to implement a sort on a keyvalue pair list; e.g.:

  1.     @kvlist = unpairs sort { $a->key cmp $b->key } pairs @kvlist

pairkeys

  1.     my @keys = pairkeys @kvlist;

Since version 1.29.

A convenient shortcut to operating on even-sized lists of pairs, this function returns a list of the the first values of each of the pairs in the given list. It is a more efficient version of

  1.     @keys = pairmap { $a } @kvlist

pairvalues

  1.     my @values = pairvalues @kvlist;

Since version 1.29.

A convenient shortcut to operating on even-sized lists of pairs, this function returns a list of the the second values of each of the pairs in the given list. It is a more efficient version of

  1.     @values = pairmap { $b } @kvlist

pairgrep

  1.     my @kvlist = pairgrep { BLOCK } @kvlist;
  3.     my $count = pairgrep { BLOCK } @kvlist;

Since version 1.29.

Similar to perl's grep keyword, but interprets the given list as an even-sized list of pairs. It invokes the BLOCK multiple times, in scalar context, with $a and $b set to successive pairs of values from the @kvlist .

Returns an even-sized list of those pairs for which the BLOCK returned true in list context, or the count of the number of pairs in scalar context. (Note, therefore, in scalar context that it returns a number half the size of the count of items it would have returned in list context).

  1.     @subset = pairgrep { $a =~ m/^[[:upper:]]+$/ } @kvlist

As with grep aliasing $_ to list elements, pairgrep aliases $a and $b to elements of the given list. Any modifications of it by the code block will be visible to the caller.

pairfirst

  1.     my ( $key, $val ) = pairfirst { BLOCK } @kvlist;
  3.     my $found = pairfirst { BLOCK } @kvlist;

Since version 1.30.

Similar to the first function, but interprets the given list as an even-sized list of pairs. It invokes the BLOCK multiple times, in scalar context, with $a and $b set to successive pairs of values from the @kvlist .

Returns the first pair of values from the list for which the BLOCK returned true in list context, or an empty list of no such pair was found. In scalar context it returns a simple boolean value, rather than either the key or the value found.

  1.     ( $key, $value ) = pairfirst { $a =~ m/^[[:upper:]]+$/ } @kvlist

As with grep aliasing $_ to list elements, pairfirst aliases $a and $b to elements of the given list. Any modifications of it by the code block will be visible to the caller.

pairmap

  1.     my @list = pairmap { BLOCK } @kvlist;
  3.     my $count = pairmap { BLOCK } @kvlist;

Since version 1.29.

Similar to perl's map keyword, but interprets the given list as an even-sized list of pairs. It invokes the BLOCK multiple times, in list context, with $a and $b set to successive pairs of values from the @kvlist .

Returns the concatenation of all the values returned by the BLOCK in list context, or the count of the number of items that would have been returned in scalar context.

  1.     @result = pairmap { "The key $a has value $b" } @kvlist

As with map aliasing $_ to list elements, pairmap aliases $a and $b to elements of the given list. Any modifications of it by the code block will be visible to the caller.

See KNOWN BUGS for a known-bug with pairmap , and a workaround.

OTHER FUNCTIONS

shuffle

  1.     my @values = shuffle @values;

Returns the values of the input in a random order

  1.     @cards = shuffle 0..51      # 0..51 in a random order

KNOWN BUGS

RT #95409

https://rt.cpan.org/Ticket/Display.html?id=95409

If the block of code given to pairmap contains lexical variables that are captured by a returned closure, and the closure is executed after the block has been re-used for the next iteration, these lexicals will not see the correct values. For example:

  1.  my @subs = pairmap {
  2.     my $var = "$a is $b";
  3.     sub { print "$var\n" };
  4.  } one => 1, two => 2, three => 3;
  6.  $_->() for @subs;

Will incorrectly print

  1.  three is 3
  2.  three is 3
  3.  three is 3

This is due to the performance optimisation of using MULTICALL for the code block, which means that fresh SVs do not get allocated for each call to the block. Instead, the same SV is re-assigned for each iteration, and all the closures will share the value seen on the final iteration.

To work around this bug, surround the code with a second set of braces. This creates an inner block that defeats the MULTICALL logic, and does get fresh SVs allocated each time:

  1.  my @subs = pairmap {
  2.     {
  3.        my $var = "$a is $b";
  4.        sub { print "$var\n"; }
  5.     }
  6.  } one => 1, two => 2, three => 3;

This bug only affects closures that are generated by the block but used afterwards. Lexical variables that are only used during the lifetime of the block's execution will take their individual values for each invocation, as normal.

SUGGESTED ADDITIONS

The following are additions that have been requested, but I have been reluctant to add due to them being very simple to implement in perl

  1.   # How many elements are true
  3.   sub true { scalar grep { $_ } @_ }
  5.   # How many elements are false
  7.   sub false { scalar grep { !$_ } @_ }

SEE ALSO

Scalar::Util, List::MoreUtils

COPYRIGHT

Copyright (c) 1997-2007 Graham Barr <gbarr@pobox.com>. All rights reserved. This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Recent additions and current maintenance by Paul Evans, <leonerd@leonerd.org.uk>.